相場の方向性を示し
大相場を支えるパラボリック
目次
パラボリックとは
パラボリックの計算方法
パラボリックのチャートの作り方
パラボリックは予測できる
パラボリックとはローソク足の上下に日々マーキングを付け現在が上昇相場なのか下落相場なのかを判断するものです。 視覚的に非常に理解しやすく見方も上にあるか、下にあるかの２通りしかなく単純な指標です。
見た目は単純ですが理論は難しく、どんな相場も永遠には続かないという前提で構成されています。 単純な分騙しも多く揉み合い相場では何の役にも立たず、大相場でこそ効果を発揮する指標となります。
揉み合いではＲＳＩやストキャスティクスを使って揉み合いから脱却したらパラボリックを併用すると言った戦略が考えられます。
螢舎が一番初めに取り組んだ難しい部類の株式分析指標であり、そういう意味では思い入れがある指標です。 パラボリックは見た目は単純な割りに計算方法が複雑です。 日が経過する毎に指標が加速して日々線に追いつく加速ファクターという要素を含んでおり一概には計算ができません。 その他の指標のように単純に２〜３列でできるものではありません。使用するものは次のとおりです。
高値・安値・EP（上昇相場の時は最高値・下落相場の時は最安値）・COUNT（連続日数）・AF（加速係数）・SARです。 SARがチャート上に表示されるパラボリックの指標となります。
一つずつ解説しますと、まず高値安値は単純に４本足から。
EPについては、上昇相場の場合（SARがローソク足より下にある場合）は、次の式によります。
EP=MAX(前日のEP,本日高値)
逆に下落相場の場合（SARがローソク足より上にある場合）は、次の式によります。
EP=MIN(前日のEP,本日安値)
つまり、高値または安値が更新される毎にEPが変化し、更新されない場合は前日の値を保持するということとなります。
COUNTについては連続日数の名のとおり、SARの転換後何日が経過したかを表します。
COUNT=SARが逆転したら1、継続なら前日のCOUNT+1
AFについては、加速係数という名がついているだけあって、だんだん加速していきます。
通常は0.02から始まり0.02ずつ増え、0.20を上限とします。ここを色々と変化させる事で騙しを排除したり、
転換を早く掴んだり選択します。騙しが少ないという事はその分変化の対応が遅れるという事であり、バランスが重要です。
どのような時に加速するかというと、EPが更新された時です。EPが更新されると0.02ずつ値が増えます。
この指標はSARをどれだけ進捗させるかの計算根拠となります。
一番重要なSARについては、次の計算式によります。
SAR=前日のSAR-(前日のSAR-EP)×AF
つまり、前日のSARとEPの差を加速係数の分だけ縮めるという事です。EPが進捗するとSARとEPの開きも当然大きくなるのですが、
その分加速係数も大きくしてより日々線に近づけます。そして相場の終焉で日々線が揉み合となる時点でSARが追いついて相場の転換とともに指標も転換する。
これがどんな相場も永遠には続かないという前提で作成された指標です。チャートだけ見るとただの○印が並んでいるだけですが、
意味を知るとこんな奥深いのです。
最後に、転換した後の最初のSARの位置ですがこれにももちろん決まりがあります。
上昇から下落へ転換したら、転換直前の上昇相場中の高値。
下落から上昇へ転換したら、転換直前の下落相場中の安値、となります。
おおよそ直前のEPの値となりますが、揉み合いがあるとそうもいきません。厳密な計算方法については次章で説明します。
| Ａ | Ｂ | Ｃ | Ｄ | Ｅ | Ｆ | Ｇ | Ｈ | Ｉ | Ｊ | |
| 1 | 日付 | 始値 | 高値 | 安値 | 終値 | EP | COUNT | AF | SAR | SAR2 |
| 2 | 1/4 | 1,140 | 1,150 | 1,124 | 1,128 | 1,124 | -1 | 0.02 | 1,150 | 1,150 |
| 3 | 1/5 | 1,098 | 1,100 | 1,063 | 1,077 | 1,063 | -2 | 0.04 | 1,149 | 1,146 |
| 4 | 1/9 | 1,077 | 1,101 | 1,053 | 1,070 | 1,053 | -3 | 0.06 | 1,146 | 1,140 |
パラボリックは初日から計算できます。ただし、一回転換があるまでは概算での算出となります。
まずはローソク足を作るために始値〜終値までを既述。 Ｆ列にEP、Ｇ列にCOUNT、Ｈ列にAF、Ｉ列にSAR、Ｊ列にSAR2を配置します。以下、順番に数式を解説します。
F列の初めは概算です。
F2のセルに以下の数式を入力します。
=D2
F3のセルに以下の数式を入力します。
=IF(D2>I2,MAX(C3,F2),MIN(D3,F2))
IF式における最初の判定にて現在SARがローソク足より上にあるか下にあるかを判定した上で進捗状況をMAX関数とMIN関数を用いて計算します。
次にG列です。COUNTはSARが下にある場合は正数、上にある場合は負数で表します。
正数（上昇相場）の時に当日安値がSARを下回ったら負数に転換。負数の時はその逆です。
まず概算でG2のセルには-1を入力します。
G3のセルには以下の数式を入力します。
=IF(G2>0,IF(J2>D3,-1,G2+1),IF(J2<C3,1,G2-1))
次にH列です。AFは加速係数です。0.02から始まり最大は0.20であると解説しました。
これは標準であり、好きな値を当てはめますが、ここでの解説は標準を用います。適宜応用してください。
まず概算でH2のセルには0.02を入力します。
H3のセルには以下の数式を入力します。
=IF(ABS(G3)=1,0.02,IF(F2=F3,H2,MIN(0.2,H2+0.02)))
MIN(0.2,H2+0.02)の数式で0.20に0.02を足しても0.20を越えない設定となります。
問題のI列です。SARが一番重要であり、計算式も複雑です。よく読んで理解してください。
I2のセルには概算で以下の数式を入力します。
=C2
I3のセルには以下の数式を入力します。
=IF(G2>0,IF(G3>0,J2,MAX(C2:OFFSET(C2,,,-ABS(G2))))
,IF(G3<0,J2,MIN(D2:OFFSET(D2,,,-ABS(G2)))))
MAX(C2:OFFSET(C2,,,-ABS(G2)))の意味はわかりにくいと思いますが、OFFSET関数でCOUNTセルに計算された日数分遡って最大の値を取りに行くよう設定されています。
これが計算できないとパラボリックは成り立ちません。
最後のJ列です。この数値の目的ははSARの翌日分を仮に算出する事にあり、転換はこの数値を持って判断します。
I列の計算過程にも組み込まれていますのでJ列の数式も完成させないとI列も正しい結果が出ません。
これが冒頭で記載した【SAR=前日のSAR-(前日のSAR-EP)×AF】の部分になります。
=I2-(I2-F2)*H2
ローソク足との複合グラフを作成する場合はExcelでチャートを作成（一般的な方法）とExcelでチャートを作成（螢舎独自の方法）を参考にしてください。
完成すると下のようなチャートができます。
△クリックすると拡大します△
パラボリックとしてはこれで完成です。 ここまで読んでいただければ理解していただけると思いますが、パラボリックは高値または安値がSARに触れるまで方向転換はありません。 そこで、翌日のSARを仮計算できるように、数日のSARを予測できると判断します。せいぜい5〜6日が限度かと思います。 それ以上の予測は現実的ではなく意味が無いからです。しかし理論上は何日でも予測できます。 そこで数日のSARを予測する事によって「○日後には日々線と絡んで来るだろう」と先を見通す事ができ、 それが理解できればSARを目安に逆指値で売買を成立させる方法も有効かと思います。その為にSARの動きを具体的に予測してみましょう。
必要なものは追加の2行です。K列には予測の日数を、L列列には予測の値を入力します。
| Ａ | Ｂ | Ｃ | Ｄ | Ｅ | Ｆ | Ｇ | Ｈ | Ｉ | Ｊ | Ｋ | Ｌ | |
| 1 | 日付 | 始値 | 高値 | 安値 | 終値 | EP | COUNT | AF | SAR | SAR2 | 予測日 | 予測SAR |
| ・ | ||||||||||||
| 122 | 6/29 | 2,035 | 2,070 | 2,015 | 2,065 | 1,915 | -15 | 0.10 | 2,151 | 2,127 | 0 | 0 |
| 123 | 1 | 2,127 |
=IF(AND(A2="",COUNTIF(K$1:K1,6)=0),K1+1,0)
L2のセルに以下の数式を入力します。
=IF(K2=0,0,OFFSET(I2,-1,,-1)-(OFFSET(I2,-1,,-1)-OFFSET(F2,-1,,-1)) *OFFSET(H2,-1,,-1))
今回は6日先まで予測を立てます。日数を変更する場合はK列のCOUNTIF式内の6の値を任意の値に変更しましょう。 あとは日々データを入力した6日先までコピーするだけです。先ほど作成したチャートにL列の値を追加し、種類を散布図にします。 通常のSARと区別できるよう色を変えたりマーカーの大きさを変えると良いでしょう。完成すると次のようになります。 今の価格を維持しても3日後程度にはSARと重なりそうだ、と今後の動きが少し見えてきます。
パラボリックの特性からして、この予測より早く動く事はあっても遅くなる事はありません。
△クリックすると拡大します△
